$!	TxxyyDaabbccdd
$!      xxyy - Adresse
$!      aa   - Anzahl 1/4-Stunden-Schlaege
$!      bb   - Anzahl 1/1-Stunden-Schlaege
$!      cc   - Dauer Gelaeut in Sekunden 
$!      dd   - Anzahl Durchgaenge Glockenspiel
$!	Alle Werte HEX
$
$! Variablen vorbesetzen
$!
$	FILE = F$ENVIRONMENT("PROCEDURE")
$	AA = "00"
$	BB = "00"
$	CC = "00"
$	DD = "00"
$
$! Zeit feststellen und Job zur naechsten 1/4 Stunde schedulen.
$!
$	HR = F$CVTIME(,,"HOUR")
$	MI = F$CVTIME(,,"MINUTE")
$	IF F$CVTIME(,,"MINUTE") .LTS. 15 
$	 THEN 
$	  SUBMIT 'FILE'/NOLOG/NOPRINT/RESTART/QUEUE=LGB$BATCH/AFTER='HR':15
$	  GOTO EXEC
$	ENDIF
$	IF F$CVTIME(,,"MINUTE") .LTS. 30 
$	 THEN 
$	  SUBMIT 'FILE'/NOLOG/NOPRINT/RESTART/QUEUE=LGB$BATCH/AFTER='HR':30
$	  GOTO EXEC
$	ENDIF
$	IF F$CVTIME(,,"MINUTE") .LTS. 45 
$	 THEN 
$	  SUBMIT 'FILE'/NOLOG/NOPRINT/RESTART/QUEUE=LGB$BATCH/AFTER='HR':45
$	  GOTO EXEC
$	ENDIF
$	IF F$CVTIME(,,"MINUTE") .GES. 45 
$	 THEN 
$	  HR = F$INTEGER(HR) + 1
$	  IF HR .EQ. 24 THEN HR = "00"
$	  HR = F$STRING(HR)
$	  IF HR .EQS. "00" 
$	   THEN 
$	    SUBMIT 'FILE'/NOLOG/NOPRINT/RESTART/QUEUE=LGB$BATCH/AFTER="TOMORROW"
$	   ELSE
$	    SUBMIT 'FILE'/NOLOG/NOPRINT/RESTART/QUEUE=LGB$BATCH/AFTER='HR':00
$	  ENDIF
$	  GOTO EXEC
$	ENDIF
$ EXEC:
$! Anzahl Glockenschlaege passend zur Zeit festlegen.
$!
$	IF MI .EQS. "15" THEN AA = "01"
$	IF MI .EQS. "30" THEN AA = "02"
$	IF MI .EQS. "45" THEN AA = "03"
$	IF MI .EQS. "00" 
$	 THEN
$	  AA = "04"
$	  IF HR .EQS. 11 .OR. HR .EQS. 17 THEN CC = "1E"
$	  IF HR .EQS. 12 .OR. HR .EQS. 18 THEN DD = "0A"
$	  IF HR .GES. 13 THEN HR = F$INTEGER(HR) - 12
$	  IF HR .EQS. "00" THEN HR = "12"
$	  BB = F$FAO("!XB",F$INTEGER(HR))
$	ENDIF
$
$! Anlage eingeschaltet ? Wenn ja, laeuten
$!
$	TCPIP PING/NUM=1 10.1.1.77
$	IF $SEVERITY .NE. 1 THEN EXIT
$	LYNX -dump "http://10.1.1.77/Y?T0108D''AA'''BB'''CC'''DD'"